Tworzenie przydatnych plików wsadowych Windows, dzięki którym usprawnimy i zautomatyzujemy pracę w nim

Możemy zautomatyzować wiele zadań na komputerze z systemem Windows 11 za pomocą plików wsadowych.

Co to jest jest plik wsadowy?

Plik wsadowy to plik zawierający jedno lub więcej poleceń do wykonania. Zamiast wpisywać te polecenia w "Wierszu poleceń (CMD)" lub programie "PowerShell", tworzymy plik, który uruchamia te polecenia przy każdym uruchomieniu. Pozwala to na realizację zadań zawartych w tych poleceniach.

Plik wsadowy ma rozszerzenie „.bat” . Pliki wsadowe uruchamia się w taki sam sposób, jak inne pliki – wystarczy dwukrotnie kliknąć plik, aby go uruchomić. Do otwierania plików wsadowych nie są potrzebne żadne dodatkowe aplikacje innych firm.

Tworzenie plików wsadowych w Windows

Tworzenie pliku wsadowego nie jest skomplikowane, to jak tworzenie dokumentu w Notatniku. Tworzymy nowy plik w edytorze tekstu , dodajemy potrzebne polecenia i zapisujemy plik jako plik wsadowy. System uruchomi plik gdy klikniemy na niego dwukrotnie prawym przyciskiem myszy, o ile jest to prawidłowy plik wsadowy i wszystko jest w nim zawarte poprawnie..

Aby utworzyć plik wsadowy w systemie Windows 10 \ 11, otwieramy wyszukiwarkę systemu Windows (naciskamy skrót na klawiaturze Windows + S), wpisujemy „Notatnik” i uruchomiamy aplikację. Wpisujemy teraz polecenia, które chcemy dodać do pliku. Po wpisaniu poleceń, z paska menu Notatnika wybieramy opcję:

Plik >> Zapisz jako (lub naciskamy Ctrl+Shift+S)

W oknie „Zapisz jako” wybieramy lokalizację, w której chcemy zapisać plik wsadowy. Klikamy menu rozwijane „Zapisz jako typ” i wybieramy „Wszystkie pliki”. Zaznacz pole „Nazwa pliku”, wpisujemy nazwę pliku wsadowego, dodajemy „..bat” na końcu nazwy pliku, aby utworzyć plik wsadowy, i klikamy „Zapisz”.

Plik wsadowy jest już gotowy. Aby go uruchomić, klikamy go dwukrotnie. Jeśli plik wsadowy wymaga uprawnień administratora (np. do usuwania plików tymczasowych), klikamy plik prawym przyciskiem myszy i wybieramy opcję „Uruchom jako administrator”. Upewniamy się, że w oknie Kontroli konta użytkownika wybrano opcję „Tak”.

Jeśli zawsze chcemy uruchamiać plik wsadowy jako administrator (dzięki temu nie będziemy musieli za każdym razem klikać pliku prawym przyciskiem myszy i wybierać „Uruchom jako administrator”), klikamy plik wsadowy prawym przyciskiem myszy i wybieramy:

Pokaż więcej opcji >> Wyślij do >> Pulpit (Utwórz skrót).

Klikamy prawym przyciskiem myszy nowo utworzony skrót i wybieramy „Właściwości”. Przechodzimy do zakładki „Skrót”, klikamy „Zaawansowane”, włączamy opcję „Uruchom jako administrator”, wybieramy „OK”, a następnie „Zastosuj”, po czym kliknij „OK”.

Gotowe, to na tyle.

Kilka przydatnych plików wsadowych dla Windows

1. Resetowanie sieci i zapory w Windows

Gdy mamy problemy z siecią , zresetowanie adresu IP komputera i wyczyszczenie pamięci podręcznej DNS pomaga je rozwiązać. Dodatkowo możemy rozbudować skrypt tak aby zresetować jeszcze zaporę sieciową i Winsock, który usuwa uszkodzone LSP i warstwy pośrednie. Możemy użyć poniższego kodu w pliku wsadowym, aby wykonać te zadania.

@echo off

title Network Reset Tool

echo Resetting network settings...

echo.

echo [1/4] Resetting TCP/IP stack...

netsh int ip reset

echo.

echo [2/4] Resetting Winsock...

netsh winsock reset

echo.

echo [3/4] Flushing DNS cache...

ipconfig /flushdns

echo.

echo [4/4] Resetting Windows Firewall...

netsh advfirewall reset

echo.

echo Network reset completed.

echo.

:ASK

set /p choice=Restart computer now? (Y/N):

if /I "%choice%"=="Y" goto RESTART

if /I "%choice%"=="N" goto END

echo Invalid choice. Please type Y or N.

goto ASK

:RESTART

shutdown /r /t 5

goto END

:END

echo Exiting...

pause

Wersja z menu i wyborem opcji:

@echo off

title Centrum Naprawy Sieci (Menu)

color 0b

:MENU

cls

echo =========================================

echo MENU NAPRAWY SIECI I SYSTEMU

echo =========================================

echo [1] Resetuj stos TCP/IP i Winsock

echo [2] Wyczysc pamiec DNS (Flush)

echo [3] Odswiez adres IP (Release/Renew)

echo [4] Resetuj Zapore Windows (Firewall)

echo [5] Test polaczenia (Ping) + Log

echo [6] Uruchom diagnostyke systemowa

echo [7] Restart komputera

echo [8] Wyjscie

echo =========================================

set /p opt="Wybierz opcje (1-8): "

if %opt%==1 goto RESET_NET

if %opt%==2 goto FLUSH_DNS

if %opt%==3 goto RENEW_IP

if %opt%==4 goto FIREWALL

if %opt%==5 goto PING_TEST

if %opt%==6 goto DIAG

if %opt%==7 goto REBOOT

if %opt%==8 exit

goto MENU

:RESET_NET

echo Resetowanie...

netsh int ip reset >nul

netsh winsock reset >nul

echo Gotowe.

pause

goto MENU

:FLUSH_DNS

ipconfig /flushdns

echo Pamiec DNS wyczyszczona.

pause

goto MENU

:RENEW_IP

echo Odswiezanie adresu IP...

ipconfig /release >nul

ipconfig /renew

pause

goto MENU

:FIREWALL

echo Przywracanie domyslnych ustawien zapory...

netsh advfirewall reset

pause

goto MENU

:PING_TEST

echo Sprawdzanie polaczenia...

ping 8.8.8.8 -n 4

echo Wynik zapisano w logu na pulpicie.

date /t > "%USERPROFILE%\Desktop\PingLog.txt"

time /t >> "%USERPROFILE%\Desktop\PingLog.txt"

ping 8.8.8.8 -n 4 >> "%USERPROFILE%\Desktop\PingLog.txt"

pause

goto MENU

:DIAG

msdt.exe /id NetworkDiagnosticsNetworkAdapter

goto MENU

:REBOOT

shutdown /r /t 10

exit

2. Przełączanie się między trybem ciemnym i jasnym w Windows

W systemie Windows 11 dostępne są tryby jasny i ciemny. Można tworzyć pliki wsadowe umożliwiające przełączanie się między tymi trybami.

Aby przełączyć się na tryb ciemny:

@echo off

reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Themes\Personalize" /v AppsUseLightTheme /t REG_DWORD /d 0 /f

echo Switched to Dark Mode.

pause

Aby przełączyć się na tryb jasny:

@echo off

reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Themes\Personalize" /v AppsUseLightTheme /t REG_DWORD /d 1 /f

echo Switched to Light Mode.

pause

3. Tworzenie punktu przywracania systemu

Utworzenie punktu przywracania systemu jest ważne, gdy planujemy wprowadzić znaczące zmiany w systemie. Ten punkt przywracania pozwala cofnąć zmiany w razie awarii gdy co pójdzie nie tak. W kodzie możemy zastąpić „RestorePointName” dowolną własną nazwą.

@echo off

echo Creating System Restore Point...

wmic.exe /Namespace:\\root\default Path SystemRestore Call CreateRestorePoint "RestorePointName", 100, 7

echo System Restore Point created.

pause

Lub:

@echo off

echo Tworzenie punktu przywracania systemu...

powershell -ExecutionPolicy Bypass -Command "Checkpoint-Computer -Description 'PunktPrzywracaniaSystemu' -RestorePointType 'MODIFY_SETTINGS'"

echo.

echo Jesli nie widzisz bledu powyzej, punkt przywracania zostal utworzony.

pause

Lub:

@echo off

setlocal enabledelayedexpansion

:: ============================

:: 1. USTAWIENIA

:: ============================

:: Dynamiczna nazwa punktu

for /f "tokens=1-5 delims=.:/ " %%a in ("%date% %time%") do (

set ROK=%%c

set MIES=%%b

set DZIEN=%%a

set GODZ=%%d

set MIN=%%e

)

set NAZWA=Punkt_%ROK%-%MIES%-%DZIEN%_%GODZ%-%MIN%

:: Plik logu

set LOG=%~dp0restore_log.txt

echo =============================================== >> "%LOG%"

echo [%date% %time%] Start operacji >> "%LOG%"

echo Nazwa punktu: %NAZWA% >> "%LOG%"

echo.

echo Sprawdzanie, czy Ochrona systemu jest wlaczona...

:: ============================

:: 2. SPRAWDZENIE OCHRONY SYSTEMU

:: ============================

powershell -Command "Get-ComputerRestorePoint" >nul 2>&1

if %errorlevel% neq 0 (

echo BLAD: Ochrona systemu jest WYLACZONA! >> "%LOG%"

echo Ochrona systemu jest WYLACZONA!

echo Wlacz ja w: Panel sterowania → System → Ochrona systemu.

echo.

pause

exit /b 1

)

echo Ochrona systemu jest wlaczona. >> "%LOG%"

echo OK.

:: ============================

:: 3. WYLACZENIE LIMITU 24h

:: ============================

echo.

echo Wylaczanie limitu 24h...

reg add "HKLM\Software\Microsoft\Windows NT\CurrentVersion\SystemRestore" ^

/v SystemRestorePointCreationFrequency /t REG_DWORD /d 0 /f >> "%LOG%" 2>&1

echo Limit 24h wylaczony. >> "%LOG%"

:: ============================

:: 4. TWORZENIE PUNKTU PRZYWRACANIA

:: ============================

echo.

echo Tworzenie punktu przywracania: %NAZWA% ...

echo Tworzenie punktu przywracania: %NAZWA% >> "%LOG%"

powershell -ExecutionPolicy Bypass -Command ^

"Checkpoint-Computer -Description '%NAZWA%' -RestorePointType 'MODIFY_SETTINGS'" >> "%LOG%" 2>&1

if %errorlevel% neq 0 (

echo BLAD podczas tworzenia punktu! >> "%LOG%"

echo BLAD podczas tworzenia punktu przywracania!

echo Szczegoly w pliku restore_log.txt

echo.

pause

exit /b 1

)

echo Punkt przywracania utworzony. >> "%LOG%"

echo Gotowe.

echo.

echo Szczegoly zapisane w restore_log.txt

pause

exit /b 0

Ostatnia werjs pomija linit 24 H na tworzenie punktu i tworzy log z działania w miejscu pliku ".bat". Tworzy tez dynamiczne nazwy punktów przywracania.

Tu pamiętajcie aby plik uruchamiać jako administrator przez p. klik myszki na plik i wybór odpowiedniej opcji z menu.

3. Opróżnianie kosza Windows

Możemy utworzyć plik wsadowy, który automatycznie usunie całą zawartość Kosza . Dzięki temu zwolnimy miejsce na dysku twardym. Aby to zrobić, użyj następujących poleceń w pliku wsadowym.

@echo off

echo Emptying Recycle Bin for all drives...

powershell -Command "Clear-RecycleBin -Force -ErrorAction Ignore"

echo Recycle Bin emptied.

pause

4. Czyszczenie plików tymczasowych

Usunięcie plików tymczasowych pomoże zwolnić miejsce na dysku i uporządkować komputer.

@echo off

echo Czyszczenie plików tymczasowych...

rem Usuwanie plików

del /q /f /s "%temp%\*"

rem Usuwanie pustych podfolderów

for /d %%i in ("%temp%\*") do rd /s /q "%%i"

echo Gotowe.

pause

5. Uruchamianie wielu aplikacji programów jednoczenie

Jeśli często uruchamiamy określone aplikacje jedna po drugiej, możemy utworzyć plik wsadowy, który automatycznie uruchomi wszystkie te aplikacje . Możemy określić aplikacje, które mają zostać uruchomione, w poleceniach. Przygodowy plik wsadowy:

@echo off

echo Launching apps...

start explorer

start chrome

start "" AppPath

echo All apps launched.

pause

W skrypcie zastępujemy „AppPath” pełną ścieżką do pliku wykonywalnego aplikacji, którą chcemy uruchomić. Pamiętajcie, aby ująć ścieżkę w cudzysłów. Poniżej przykładowy skrypt, który uruchamia kilka aplikacji naraz:

@echo off

CD "C:\Program Files\Google\Chrome\Application"

Start chrome.exe

CD C:\Users\andrz\AppData\Local\Programs\signal-desktop

Start Signal.exe

CD "C:\Program Files\Electronic Arts\EA Desktop\EA Desktop"

Start EALauncher.exe

CD "C:\Program Files (x86)\GOG Galaxy"

Start GalaxyClient.exe

CD "C:\Program Files (x86)\Ubisoft\Ubisoft Game Launcher"

Start UbisoftConnect.exe

cd "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Clementine\"

start Clementine.lnk

cd "C:\Program Files\Ferdium\"

start Ferdium.exe

cd "C:\Users\andrz\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Steam\"

start Steam.lnk

end

6. Uruchamianie kilku tron WWW naraz w domyślnej przeglądarce.

Przed pełnym adresem strony w skrypcie musimy dać słowo "start" dla każdej strony. Ten skrypt otworzy strony w przeglądarce, każda strona w osobnej zakładce. Przykładowy skrypt:

@echo off

start https://www.youtube.com/channel/UCCjhoNgWSDY3VU64hLp42pg

start https://kaciksprzetowy.blogspot.com/

start https://music.youtube.com/

start https://www.fixitpc.pl/

start https://forum.instalki.pl/

start https://www.instalki.pl/

start https://www.youtube.com/

start https://sites.google.com/site/twierdzaciemnosci/twierdza

end

7. Tworzenie kopii zapasowej plików i folderów

Aby wykonać kopię zapasową wybranych plików i folderów, możemy utworzyć plik wsadowy, który automatycznie kopiuje elementy z jednego źródła i wkleja je w innej ścieżce. W tym skrypcie zastępujemy „SourcePath” ścieżką, z której chcemy skopiować elementy. Zastępujemy „DestinationPath” ścieżką, w której chcemy zapisać pliki.

W tym przypadku parametr „/e” zapewnia również skopiowanie pustych folderów. Parametr „/i” tworzy folder docelowy, jeśli jeszcze nie istnieje. Parametr „/h” kopiuje ukryte pliki. Parametr „/y” nadpisuje pliki bez monitów.

@echo off

echo Backing up files...

xcopy "SourcePath" "DestinationPath" /e /i /h /y

echo Backup completed.

pause

Aktualizacja: 23.02.2026

Artykuł na licencji Uznanie autorstwa-Użycie niekomercyjne-Na tych samych warunkach 3.0 Polska (CC BY-NC-SA 3.0 PL)

Copy Success

Szukaj na tym blogu

Kącik porad dla Windows, Linux, Androida i ogólnie komputerów